home *** CD-ROM | disk | FTP | other *** search
/ TeX 1995 July / TeX CD-ROM July 1995 (Disc 1)(Walnut Creek)(1995).ISO / biblio / bibtex / contrib / dinalpha.bst < prev    next >
Text File  |  1994-11-24  |  34KB  |  1,520 lines
  1. %%  DINALPHA.BST         ---  ß-Version v. 9/11/94 K.F.Lorenzen
  2. %%
  3. %%  entwickelt aus BibTeX standard bibliography style `alpha'
  4. %%  gemaess der deutschen Zitiernorm DIN 1505 Teil 2
  5. %%        von Klaus F. Lorenzen, Hamburg  5/2/94 bis 28/3/94 
  6. %%        Jobst-Hartmut Lueddecke, Hamburg  habe ich fuer Verbesserungsvor-
  7. %%        schlaege und stete Unterstuetzung bei der Implementierung
  8. %%        auf der DEC-Rechenanlage des RZ der FH Hamburg zu danken
  9. %%        Oren Patashnik, dem BIBTEX-Schoepfer zugeeignet
  10. %%  Dieser style produziert Literaturzitate in Literaturverzeichnissen
  11. %%  gemaess der deutschen Norm DIN 1505, Teil 2 vom Jan. 1984.
  12. %%  Es gibt eine Reihe prinzipieller Unterschiede zwischen der US- und 
  13. %%  der deutschen Zitierkonvention. Daher ist auch keine 1-1-deutige  
  14. %%  Abbildung der beiden Regelwerke aufeinander moeglich. 
  15. %%  Dennoch laesst sich in fast allen Faellen problemlos ein Original-bib-file
  16. %%  (d.i. die Datenbank, die die bibliographischen Informationen enthaelt)
  17. %%  wahlweise nach US-Norm oder deutscher DIN-Norm verarbeiten. 
  18. %%  [Beispiel: Produzieren Sie mit der XAMPL.bib-Datenbank aus dem Original-
  19. %%  paket 2 verschiedene Literaturverzeichnisse.]     Zu Gunsten
  20. %%  der Allgemeingueltigkeit von bib-files ist bei den Publikationstypen
  21. %%  (entry-types) und den bibliographischen Kategorien (fields) in Zweifels-
  22. %%  faellen immer (ja, mit endlichen Ausnahmen) die originale US-Bedeutung 
  23. %%  beibehalten worden. Bei der Erfassung von Literaturquellen in bib-files 
  24. %%  gelten folglich die in der TEX-Literatur veroeffentlichten Regeln.
  25. %%  Kommt es dennoch zu kleineren "Schoenheitsfehlern" im fertig gesetzten 
  26. %%  output, so koennen diese so gut wie immer durch eine leicht veraenderte 
  27. %%  Erfassung im bib-file beseitigt werden.
  28. %%
  29. %%  Die entry-Funktionen booklet und phdthesis entfallen zugunsten der
  30. %%  Funktionen book und mastersthesis.
  31. %%
  32. %%  Diese beta-Version ist an der FH Hamburg seit einem halben Jahr erfolgreich
  33. %%  im Test und wird nun einem groesseren Anwenderkreis uebergeben. Eine aus-
  34. %%  fuehrliche Dokumentation mit Beispielen ist in Vorbereitung. 
  35. %%  ACHTUNG!  Aus Testgruenden, Zeitmangel und Faulheit sind noch nicht
  36. %%  alle ueberfluessigen Fehlermeldungen des Original-style ausgemerzt.
  37. %%  Ferner sind noch laengst nicht alle Programmverfeinerungen ausgekostet.
  38. %%  Das fuehrt mitunter zu Wasserfallartigen Fehlermeldungen: vergessen Sie
  39. %%  es einfach und schauen Sie sich lieber das fertige Literaturverzeichnis
  40. %%  an!
  41. %%  Aus dinalpha.bst sind analog zur Originalversion die anderen styles
  42. %%  dinplain.bst, dinunsrt.bst, dinabbr.bst abgeleitet und einsatzbereit.
  43. %%
  44. %%  Kritik, Vorschlaege usw. bitte an 
  45. %%          FH Hamburg,  Klaus F. Lorenzen, Grindelhof 30, 20146 Hamburg
  46. %%          e-mail: lorenzen@rzbt.fh-hamburg.de
  47. %%
  48. % version 0.99a for BibTeX versions 0.99a or later, LaTeX version 2.09.
  49. % Copyright (C) 1985, all rights reserved.
  50. % Copying of this file is authorized only if either
  51. % (1) you make absolutely no changes to your copy, including name, or
  52. % (2) if you do make changes, you name it something other than
  53. % dinbst.doc, dinplain.bst, dinunsrt.bst, dinalpha.bst, and dinabbrv.bst.
  54. % This restriction helps ensure that all standard styles are identical.
  55. %% ==>  The file btxbst.doc has the original documentation for style 'alpha'.
  56. %%      The file dinbst.doc has the documentation for this style (`dinalpha').
  57. %%      dinbst.doc is not yet delivered (9/11/94), Lo
  58. %%
  59.  
  60. ENTRY
  61.   { address      %% 
  62.     author       %% 
  63.     booktitle    %%
  64.     chapter      %%
  65.     edition      %% 
  66.     editor       %% 
  67.     howpublished %%
  68.     institution  %%
  69.     isbn         %% neues Feld: Standardnr fuer Buecher
  70.     issn         %%  - " -    :      -"-        Zeitschriften u. Serien
  71.     journal      %% 
  72.     key          %%
  73.     month        %% 
  74.     note         %% 
  75.     number       %% 
  76.     organization %%
  77.     pages        %% 
  78.     publisher    %% 
  79.     school       %% 
  80.     series       %% 
  81.     title        %% 
  82.     type         %% 
  83.     volume       %% 
  84.     year         %% 
  85.   }
  86.   {}
  87.   { label extra.label sort.label }
  88.  
  89. INTEGERS { output.state before.all mid.sentence after.sentence after.block }
  90.  
  91. %%$$$ die folg. BOOLE'sche VAR steuern d. Ausg. ": " nach Urheber-Feldern
  92. %%    und ". - " vor ISBN oder Anmerkungen (NOTE)
  93.  
  94. INTEGERS { colon.after  period.dash }
  95.  
  96. FUNCTION {init.state.consts}
  97. { #0 'before.all :=
  98.   #1 'mid.sentence :=
  99.   #2 'after.sentence :=
  100.   #3 'after.block :=
  101.   #4 'colon.after :=
  102.   #5 'period.dash :=
  103. }
  104. INTEGERS { zahl  lang }  
  105.  
  106. STRINGS { h s t u v }    
  107.  
  108. %%$$$ neue DIN-Funktion, 16/2/94
  109.  
  110. FUNCTION {output.nonnull}
  111. { 's :=
  112.   output.state after.block =
  113.       { add.period$  write$
  114.     newline$
  115.     "\newblock " write$
  116.       }
  117.       { output.state before.all =
  118.       {  write$ }     
  119.       {  output.state colon.after =
  120.            { ": " * write$
  121.          newline$
  122.          "\newblock " write$
  123.            }
  124.            { output.state period.dash =
  125.            { ". -- " *  write$
  126.              newline$
  127.              "\newblock " write$
  128.            }
  129.            { output.state mid.sentence =
  130.                { ", " * write$ }
  131.                { " "  * write$ 
  132.              newline$
  133.              "\newblock " write$
  134.                }
  135.              if$
  136.            }
  137.         if$
  138.            }
  139.         if$
  140.        }     
  141.      if$
  142.      after.block 'output.state :=
  143.        }
  144.      if$
  145.      s 
  146. }
  147.  
  148. FUNCTION {output}
  149. { duplicate$ empty$
  150.     'pop$
  151.     'output.nonnull
  152.   if$
  153. }
  154.  
  155. FUNCTION {output.check}
  156. { 't :=
  157.   duplicate$ empty$
  158.     { pop$ "empty " t * " in " * cite$ * warning$ }
  159.     'output.nonnull
  160.   if$
  161. }
  162.  
  163. FUNCTION {output.bibitem}
  164. { newline$
  165.   "\bibitem[" write$
  166.   label write$
  167.   "]{" write$
  168.   cite$ write$
  169.   "}" write$
  170.   newline$
  171.   ""
  172.   before.all 'output.state :=
  173. }
  174.  
  175. FUNCTION {fin.entry}   %%$$$  nach DIN neu 16/2/94
  176. { write$
  177.   newline$
  178. }
  179.  
  180. FUNCTION {set.period.dash}    %% Wenn ein ". - " die Satzteile trennen soll.!
  181. { output.state before.all =
  182.     'skip$
  183.     { period.dash  'output.state := }
  184.   if$
  185. }
  186.  
  187. %%$$$ neu 16/2/94
  188. %%   prueft, ob ISBN- oder NOTE-Feld vh. ist und setzt dann ". - " davor.
  189. %%   wenn aber ein PAGES-Feld ausgegeben wurde, dann kommt nichts davor.
  190.  
  191. FUNCTION {set.period.dash.check}  
  192. { empty$                            
  193.     'skip$
  194.     'set.period.dash  
  195.   if$
  196. }
  197.  
  198. FUNCTION {set.colon.after}   %%$$$ Wenn ein ": " d. Satzteile trennen soll!
  199. { output.state before.all =
  200.     'skip$
  201.     { colon.after 'output.state  := }
  202.   if$
  203. }
  204.  
  205. %% neu / alt 17/2/94          Wenn ein " " die Satzteile trennen soll.!
  206. FUNCTION {new.sentence}
  207. { output.state before.all =
  208.      'skip$
  209.      { after.sentence 'output.state := }
  210.   if$
  211. }
  212.  
  213. %% neu 17/2/94                 Wenn ein ", " die Satzteile trennen soll.!
  214. FUNCTION { part.of.sentence }
  215. { output.state before.all =
  216.      'skip$
  217.      { mid.sentence 'output.state := }
  218.   if$
  219. }
  220.  
  221.  
  222. FUNCTION {not}
  223. {   { #0 }
  224.     { #1 }
  225.   if$
  226. }
  227.  
  228. FUNCTION {and}
  229. {   'skip$
  230.     { pop$ #0 }
  231.   if$
  232. }
  233.  
  234. FUNCTION {or}
  235. {   { pop$ #1 }
  236.     'skip$
  237.   if$
  238. }
  239.  
  240. FUNCTION {new.sentence.checka}
  241. { empty$
  242.     'skip$
  243.     'new.sentence
  244.   if$
  245. }
  246.  
  247. FUNCTION {field.or.null}
  248. { duplicate$ empty$
  249.     { pop$ "" }
  250.     'skip$
  251.   if$
  252. }
  253.  
  254. FUNCTION {emphasize}
  255. { duplicate$ empty$
  256.     { pop$ "" }
  257.     { "{\em " swap$ * "\/}" * }
  258.   if$
  259. }
  260.  
  261. INTEGERS { nameptr namesleft numnames }
  262.  
  263. STRINGS { fkt }
  264.  
  265. %% neu, setzt Autor/Hrsg. in Kapitaelchen 9/3/94
  266. FUNCTION { capitalize }
  267.  { duplicate$ empty$
  268.     { pop$ "" }
  269.     { "{\sc " swap$ * "}" * }
  270.   if$
  271. }
  272.  
  273. %%$$$ DIN-Quellenangabe : spezieller unselbst. Teil ist erschienen "In: " 
  274. %%                        dem bibliogr. selbst. Werk, z.B. Zeitschrift, Buch
  275.  
  276. %% 9/3/94
  277. FUNCTION {inquelle}
  278. { duplicate$ empty$
  279.     { pop$ "" }
  280.     { emphasize "{\bf In: }" swap$ * }
  281.   if$
  282. }
  283.  
  284. %% Vorschlag von H.Lueddecke, um Adelspraedikate beim Sortieren
  285. %% nach den(m) Vornamen aufzufuehren. Lo, 2/11/94
  286. FUNCTION {format.names}
  287. { 's :=
  288.   "" 'u  :=
  289.   #1 'nameptr :=
  290.   s num.names$ 'numnames :=
  291.   numnames 'namesleft :=
  292.     { namesleft #0 > }
  293.     {
  294. %vorher, Lue      s nameptr "{vv~}{ll}" format.name$ 't :=
  295.        s nameptr "{ll}" format.name$ 't :=
  296.        t capitalize 't :=
  297. %vorher,Lue      s nameptr "{, ff}" format.name$ 'u := 
  298.        s nameptr "{, ff}{ vv}" format.name$ 'u := 
  299.        u  text.length$  'lang :=     
  300.        #1 'zahl :=
  301.        "" 'v :=
  302.      {  zahl  lang  <  }
  303.      {  u  zahl  #1  substring$  "~"  =  
  304.            {  v  ""  =
  305.              {  u  #1  zahl  #1  -  substring$  'v :=  }
  306.              'skip$
  307.           if$
  308.           v  u  zahl  #2  substring$  *  "."  *  'v :=  }
  309.            'skip$
  310.         if$
  311.         zahl  #1  +  'zahl :=  }
  312.       while$
  313.       v  ""  =
  314.      {  u  'v :=  }
  315.      'skip$
  316.       if$
  317. %%    der string fkt enthaelt " (Hrsg.)", wenn Editorfeld nicht leer ist
  318.       t  v  *  fkt  *  't :=  %% Komma nach Nachnamen wird oben erledigt!
  319.                   %% t enthaelt nun d. formatierten Nnamen, Vnamen
  320.       nameptr #1 >
  321.      { namesleft #1 >
  322.          { " ; " * t * }
  323.          { numnames #2 >
  324.           { " " * }
  325.           'skip$
  326.            if$
  327.            t "{\sc others}" =
  328. %%                  { "et~al." * }     %% Geschmackssache
  329.             { " [~u.~a.~] " * }%%   13/2/94
  330.             { " ; " * t * }
  331.            if$
  332.            }
  333.         if$  %% Ende der namesleft-Pruefung
  334.       }
  335.         't    
  336.        %% hierdurch wird bei jed. Schleifendurchgang das sich komplet-
  337.        %% tierende Zwischen-Namensergebnis wieder auf den stack gelegt 
  338.  
  339.        if$  %%  Ende der nameptr-Pruefung
  340.  
  341.       nameptr #1 + 'nameptr :=
  342.       namesleft #1 -  'namesleft :=
  343.     }
  344.   while$  %%  Ende von { namesleft #0 > } ganz oben
  345.   "" 'fkt :=  %% fkt wird zurueckgesetzt
  346. }
  347.  
  348. %%$$$ geaendert 14/2/94
  349.  
  350. FUNCTION {format.authors}
  351. { author empty$
  352.     { "" }
  353.     { author format.names }
  354.   if$
  355. }
  356.  
  357. %%$$$ geaend. 20/2/94 Anpassung an DIN mit Autor + Hrsg. !!
  358.  
  359. FUNCTION {format.editors}
  360. { editor empty$
  361.    { author empty$
  362.        { "Weder Verfasser noch Hrsg. in " cite$ * warning$ }
  363.        'skip$ 
  364.      if$
  365.     }
  366.     { author empty$
  367.     { " (Hrsg.)" 'fkt :=  
  368.       editor format.names 
  369.     }
  370.     { " (Hrsg.)" 'fkt :=  
  371.       " ; " * editor format.names *
  372.     }
  373.       if$
  374.      }
  375.    if$
  376.  } 
  377.  
  378. %%$$$  Sonderfall: Herausgeber bei Typ incollection, 21/2/94
  379. FUNCTION {format.ed.incoll}
  380. { editor empty$
  381.      { "" }
  382.      { " (Hrsg.)" 'fkt :=  
  383.        editor format.names 
  384.      }
  385.   if$
  386. } 
  387.  
  388. %%$$$ neu 22/2/94  Neben den Herausgebern wird auch die veranstaltende
  389. %%       Koerperschaft, z.B. ein Institut, e. Gesellschaft, Organisat. genannt.
  390.  
  391. FUNCTION {format.proceed.organization}
  392. {  organization empty$
  393.       { "" }
  394.       { " / " organization * " (Veranst.)" * }
  395.    if$
  396. }
  397.  
  398. FUNCTION {format.title}
  399. { title empty$
  400.     { "" }
  401.     { title }  %% Text so wie er dasteht im Feld title
  402.   if$
  403. }
  404.  
  405. FUNCTION {n.dashify}
  406. { 't :=
  407.   ""
  408.     { t empty$ not }
  409.     { t #1 #1 substring$ "-" =
  410.     { t #1 #2 substring$ "--" = not
  411.         { "--" *
  412.           t #2 global.max$ substring$ 't :=
  413.         }
  414.         {   { t #1 #1 substring$ "-" = }
  415.         { "-" *
  416.           t #2 global.max$ substring$ 't :=
  417.         }
  418.           while$
  419.         }
  420.       if$
  421.     }
  422.     { t #1 #1 substring$ *
  423.       t #2 global.max$ substring$ 't :=
  424.     }
  425.       if$
  426.     }
  427.   while$
  428. }
  429.  
  430. %% geaendert 24/2/94
  431. FUNCTION {format.date}
  432. { year empty$
  433.     { month empty$
  434.     { "" }
  435.     { "there's a month but no year in " cite$ * warning$
  436.       month
  437.     }
  438.       if$
  439.     }
  440.     { month empty$  %% b. Buechern nur Jahr, ohne Monat ausgeb. im Impressum
  441.       'year
  442.       { month " " * year * }
  443.       if$
  444.     }
  445.   if$
  446. }
  447.  
  448. %%
  449. %%$$$  neue Fkt., 16/2/94 u. 14/3/94       das sog. Impressum
  450. FUNCTION {format.address.publisher.year}
  451. {  publisher empty$
  452.       { address empty$
  453.       { year empty$  
  454.           { "" }
  455.           { year } 
  456.         if$
  457.       }
  458.       { "Es gibt einen Verlagsort, aber keinen Verlag in " cite$ * warning$
  459.           address ", " * format.date * 
  460.       }
  461.     if$
  462.       }
  463.       { address empty$
  464.       { year empty$
  465.          { "Es gibt nur eine Verlagsangabe in " cite$ * warning$ 
  466.         publisher
  467.          }
  468.          { publisher ", " * format.date * }
  469.         if$
  470.       }
  471.       { year empty$
  472.           { address " : " * publisher * }
  473.           { address " : " * publisher * ", " * format.date * }
  474.         if$
  475.       }
  476.     if$
  477.       }
  478.   if$
  479. }
  480.  
  481. FUNCTION {format.btitle}
  482. { title emphasize
  483. }
  484.  
  485. FUNCTION {tie.or.space.connect}
  486. { duplicate$ text.length$ #3 <
  487.     { "~" }
  488.     { " " }
  489.   if$
  490.   swap$ * *
  491. }
  492.  
  493. FUNCTION {either.or.check}
  494. { empty$
  495.     'pop$
  496.     { "can't use both " swap$ * " fields in " * cite$ * warning$ }
  497.   if$
  498. }
  499.  
  500. %% neu 8/3/94 in dieser Funkt. steckt im volume empty-Teil noch ein bug, der
  501. %%            aber ignoriert werden kann; das Ergebnis ist ok.
  502. FUNCTION {format.btitle.vol}
  503. { number empty$
  504.    { series empty$
  505.      { volume empty$
  506.     { title emphasize }
  507.     { title emphasize ". Bd." * volume tie.or.space.connect }
  508.        if$
  509.      }
  510.      { volume empty$
  511.     { title emphasize }
  512.     { series emphasize ". Bd." * volume tie.or.space.connect  " : " * title * } 
  513.        if$
  514.      }
  515.      if$%% series-test
  516.    }
  517.    { title emphasize }%% wenn number ex., dann immer title-Feld
  518.   if$%% Ende number-test
  519. }
  520.  
  521. %%$$$ neu 16/2/94
  522. %%   Serien- / Reihentitel werden im Feld series gespeichert. Weist die
  523. %%   Serie eine Zaehlung der Einzeltitel auf, gibt man entweder nach DIN alles 
  524. %%   in das Feld series so ein: ---> TITEL DER SERIE  NR. (der Vorlage) <---
  525. %%   z. B.  SERIES= { Mensch und Computer 12 }. 
  526. %%   [ Die Nummer der Vorlage darf auch durch " ; " abgesetzt werden. ]
  527. %%   oder:
  528. %%   man gibt die Zaehlung in das Feld NUMBER ein, z.B. NUMBER = {12}.
  529. %%   Achtung!!
  530. %%   Bei mehrbaendigen Werken steht d. Gesamttitel im Feld SERIES und die
  531. %%   Bandzaehlung im Feld VOLUME; NUMBER darf dann nicht besetzt sein!
  532. %%   Anderenfalls liegt ein Erfassungsfehler vor, da sich Reihe u. mehrbd.
  533. %%   Werk gegenseitig ausschliessen.
  534.  
  535. FUNCTION {format.series.number.din}
  536. { volume empty$
  537.     { number empty$
  538.       { series empty$
  539.            { "" }%%   Ausstieg mit Nullstring
  540.            { "(" series * ")" * } %% d. Seriennr koennte auch gleich hier
  541.                       %% im SERIES-Feld miterfasst werden
  542.         if$
  543.       }      
  544.       { series empty$
  545.            { "(" number tie.or.space.connect ")" * 
  546.          "there's a number but no series in " cite$ * warning$ 
  547.            }
  548.            { "(" series * number tie.or.space.connect ")" * }
  549.         if$
  550.       }
  551.        if$
  552.      }
  553.      { series empty$
  554.       { "" }
  555.       { type$ "proceedings" =  %%   Sonderfall !
  556.         { "(" series * ")" * }
  557.         { "" }%%   Ausstieg mit Nullstring, s. Kommentar
  558.         if$
  559.       }%% bei gezaehlten Reihen MUSS die Reihennr. im Feld NUMBER stehen!
  560.        if$ %% wenn also d. Feld VOLUME nicht leer ist, dann liegt falsche
  561.       }     %% Erfassung vor und es erfolgt d. Ausstieg mit d. Nullstring!
  562.   if$
  563. }
  564.  
  565.  
  566. %%$$$ 16/2/94
  567. %%  Auflagenvermerke gibt man komplett, einschliesslich Abkuerzungen in 
  568. %%  das Feld edition ein: ---> EDITION= { 3., erw. und verb. Aufl. }
  569. %%  oder fremdsprachlich:      EDITION= { 2nd edition }
  570.  
  571. FUNCTION {format.edition}
  572. { edition empty$
  573.     { "" }
  574.     { edition } 
  575.   if$
  576. }
  577.  
  578. %%$$$ neu, 18/3/94
  579. FUNCTION { format.isbn.issn }
  580. { isbn empty$
  581.      { issn empty$
  582.       { "" }
  583.       { "ISSN" issn n.dashify tie.or.space.connect }
  584.        if$
  585.      }
  586.      { "ISBN" isbn n.dashify tie.or.space.connect }
  587.   if$
  588. }
  589.  
  590. %%$$$ geaendert, 21/2/94  gibt Seitenzahl bei BOOK-Typ und verwandten T. aus
  591. FUNCTION {format.pages.book}
  592. { pages empty$
  593.     { "" }
  594. %    { pages n.dashify tie.or.space.connect " S" *}
  595.     { pages "Seiten" n.dashify  tie.or.space.connect }
  596.   if$
  597. }
  598.  
  599. %%$$$  alle anderen Seitenang. zB. Zeitschrft., INBOOK usw. a la Orig., 9/3/94
  600. FUNCTION {format.pages}
  601. { pages empty$
  602.     { "" }
  603.     { "S." pages n.dashify  tie.or.space.connect } 
  604.   if$
  605. }
  606.  
  607. %%$$$ Angaben v. Jahrgang, Jahr, Heftnr., Seiten bei Artikel-Typ
  608. %%    14/3/94
  609.  
  610. FUNCTION {format.vol.year.num.pages}
  611. { volume field.or.null
  612.     year empty$
  613.       { "Es gibt einen Jahrgang, aber kein Jahr in " cite$ * warning$ }
  614.       { " (" year * ")" * * }
  615.     if$
  616.     month empty$
  617.     'skip$
  618.     { ", " month * * }
  619.     if$
  620.     number empty$
  621.     'skip$
  622.     { ", Nr. " number * *
  623. %      volume empty$
  624. %       { "there's a number but no volume in " cite$ * warning$ }
  625. %       'skip$
  626. %      if$
  627.     }
  628.     if$
  629.   pages empty$
  630.     'skip$
  631.     { duplicate$ empty$
  632.     { pop$ format.pages }%% da pages leer, wird nur "" auf stack gelegt
  633.     { ", " format.pages * *}
  634.       if$
  635.     }
  636.   if$
  637. }
  638.  
  639. %% geaendert 21/2/94
  640. FUNCTION {format.chapter.pages}
  641. { chapter empty$
  642.     'format.pages
  643.     { type empty$
  644.     { "Kapitel " }
  645.     { type }
  646.       if$
  647.       chapter tie.or.space.connect
  648.       pages empty$
  649.     'skip$
  650.     { ", " * format.pages * }
  651.       if$
  652.     }
  653.   if$
  654. }
  655.  
  656. %%$$$  geaendert 21/2/94
  657. FUNCTION {format.in.ed.booktitle.din}
  658. { booktitle empty$
  659.     { "" }
  660.     { editor empty$
  661.     { volume empty$
  662.         { "{\bf In: }" booktitle emphasize * }
  663.         { "{\bf In: }" booktitle emphasize * 
  664.           " Bd." volume tie.or.space.connect * 
  665.         }
  666.       if$
  667.     }
  668.     { volume empty$
  669.         { "{\bf In: }" format.ed.incoll * ": " * booktitle emphasize * }
  670.         { "{\bf In: }" format.ed.incoll * ": " * booktitle emphasize * 
  671.           " Bd." volume tie.or.space.connect * 
  672.         }
  673.       if$
  674.     }
  675.       if$
  676.     }
  677.   if$
  678. }
  679.  
  680. %% geaendert 1/3/94
  681. FUNCTION {format.thesis.type}
  682. { type empty$
  683.     'skip$
  684.     { pop$
  685.       type 
  686.     }
  687.   if$
  688. }
  689.  
  690. %% geaendert 23/2/94    i.Orig. wird zuerst die number, dann der type getestet
  691. FUNCTION {format.tr.number.din}
  692. { type empty$
  693.      { number empty$
  694.      { " -- Forschungsbericht" }   %%  bei Minimalangaben besser ohne "."!
  695.      { "(" number tie.or.space.connect "). -- Forschungsbericht" * }
  696.        if$
  697.      }
  698.      { number empty$
  699.      { " -- " type * }             %%  bei Minimalangaben besser ohne "."!
  700.      { "(" number tie.or.space.connect "). -- " * type * }
  701.        if$
  702.      }
  703.   if$
  704. }
  705.  
  706.  
  707. FUNCTION {format.article.crossref}
  708. { key empty$
  709.     { journal empty$
  710.     { "need key or journal for " cite$ * " to crossref " * crossref *
  711.       warning$
  712.       ""
  713.     }
  714.     { "{\bf In: }{\em " journal * "\/}" * }
  715.       if$
  716.     }
  717.     { "{\bf In: }" key * }
  718.   if$
  719.   " (siehe \cite{" * crossref * "}" * ")" *
  720. }
  721.  
  722. %%geaendert 7/3/94 und noch einmal durch Lueddecke, s.o.
  723. FUNCTION {format.crossref.editor}
  724. %vorher,Lue  { editor #1 "{vv~}{ll}" format.name$ " (Hrsg.)" *
  725.  { editor #1 "{ll}" format.name$ " (Hrsg.)" *
  726.    editor num.names$ duplicate$
  727.    #2 >
  728.     { pop$ " et~al." * }
  729.     { #2 <
  730.     'skip$
  731.     { editor #2 "{ff }{vv }{ll}{ jj}" format.name$ "others" =
  732.         { " et~al." * }
  733.         { " ; " * editor #2 "{vv~}{ll}" format.name$ * " (Hrsg.)" * }
  734.       if$
  735.     }
  736.       if$
  737.     }
  738.   if$
  739. }
  740.  
  741.  
  742. FUNCTION {format.book.crossref}
  743. { volume empty$
  744.     { "empty volume in " cite$ * "'s crossref of " * crossref * warning$
  745.       "(siehe "
  746.     }
  747.     { ". -- Bd." volume tie.or.space.connect
  748.       " von " *
  749.     }
  750.   if$
  751.   editor empty$
  752.   editor field.or.null author field.or.null =
  753.   or
  754.     { key empty$
  755.     { series empty$
  756.         { "need editor, key, or series for " cite$ * " to crossref " *
  757.           crossref * warning$
  758.           "" *
  759.         }
  760.         { "{\em " * series * "\/} (siehe " * }
  761.       if$
  762.     }
  763.     { key * }
  764.       if$
  765.     }
  766.     { format.crossref.editor * }
  767.   if$
  768.   " \cite{" * crossref * "}" * ")" *
  769. }
  770.  
  771. FUNCTION {format.incoll.inproc.crossref}
  772. { editor empty$
  773.   editor field.or.null author field.or.null =
  774.   or
  775.     { key empty$
  776.     { booktitle empty$
  777.         { "need editor, key, or booktitle for " cite$ * " to crossref " *
  778.           crossref * warning$
  779.           ""
  780.         }
  781.         { "{\bf In: }{\em " booktitle * "\/}" * }
  782.       if$
  783.     }
  784.     { "{\bf In: }" key * }
  785.       if$
  786.     }
  787.     { "{\bf In: }" format.crossref.editor * }
  788.   if$
  789.   " (siehe \cite{" * crossref * "}" * ")" *
  790. }
  791.  
  792. %%geaendert
  793. FUNCTION {article}
  794. { output.bibitem
  795.   format.authors "author" output.check
  796.   set.colon.after
  797.   format.title "title" output.check
  798.   crossref missing$
  799.     { journal inquelle output.nonnull 
  800.       new.sentence 
  801.       format.vol.year.num.pages output
  802.     }
  803.     { format.article.crossref output.nonnull }
  804.   if$
  805.   note set.period.dash.check
  806.   note output
  807.   issn set.period.dash.check
  808.   format.isbn.issn output
  809.   fin.entry
  810. }
  811.  
  812. %%$$$   geaendert, 20/2/94
  813. FUNCTION {book}
  814. { output.bibitem
  815.   author empty$
  816.     { format.editors "author and editor" output.check }
  817.     { format.authors  format.editors output.nonnull
  818.     }
  819.   if$
  820.   set.colon.after
  821.   crossref missing$
  822.     { format.btitle.vol "title" output.check }
  823.     { format.btitle "title" output.check }
  824.   if$
  825.   format.edition output  
  826.   format.address.publisher.year "publisher" output.check
  827.   new.sentence
  828.   crossref missing$
  829.     { format.series.number.din  output }
  830.     { format.book.crossref output.nonnull }
  831.   if$
  832.   new.sentence
  833.   format.pages.book output
  834.   note set.period.dash.check
  835.   note output 
  836.   isbn set.period.dash.check
  837.   format.isbn.issn output
  838.   fin.entry
  839. }
  840.  
  841. %% geaendert 23/2/94
  842. FUNCTION {inbook}
  843. { output.bibitem
  844. %% unselbst. Teile eines Buches werden am Anf. genannt, dann d selbst. Quelle 
  845.   chapter empty$
  846.     { "Keine Kapitelangaben in " cite$ * warning$ }
  847.     { type empty$
  848.      { "Kap. " }
  849.      { type }
  850.       if$
  851.      }
  852.   if$
  853.   chapter tie.or.space.connect " {\bf In: }" *
  854. %%   -------- jetzt kommt der bibliogr. selbst. Teil
  855.   author empty$
  856.     { format.editors "author and editor" output.check }
  857.     { format.authors output.nonnull
  858.     }
  859.   if$
  860.   set.colon.after
  861.   format.btitle.vol "title" output.check
  862.   crossref missing$
  863.     { format.edition output
  864.       format.address.publisher.year "publisher" output.check
  865.       new.sentence
  866.       format.series.number.din  output 
  867.       note set.period.dash.check
  868.       note output 
  869.       isbn set.period.dash.check
  870.       format.isbn.issn output
  871.     }
  872.     { format.book.crossref output.nonnull
  873.       note set.period.dash.check
  874.       note output 
  875.     }
  876.   if$
  877.   part.of.sentence
  878.   format.pages "pages" output.check
  879.   fin.entry
  880. }
  881.  
  882. %%  geaendert 21/2/94
  883. FUNCTION {incollection}
  884. { output.bibitem
  885.   format.authors "author" output.check
  886.   set.colon.after
  887.   format.title "title" output.check
  888.   crossref missing$
  889.     { format.in.ed.booktitle.din "booktitle" output.check
  890.       format.edition output
  891.       format.address.publisher.year "publisher" output.check
  892.       new.sentence
  893.       format.series.number.din  output %%$$$ 7/3/94
  894.     }
  895.     { format.incoll.inproc.crossref output.nonnull }
  896.   if$
  897.   note set.period.dash.check
  898.   note output 
  899.   isbn set.period.dash.check
  900.   issn set.period.dash.check
  901.   format.isbn.issn output
  902.   part.of.sentence
  903.   format.chapter.pages output
  904.   fin.entry
  905. }
  906.  
  907. %%  geaendert 22/2/94
  908. FUNCTION {inproceedings}
  909. { output.bibitem
  910.   format.authors "author" output.check
  911.   set.colon.after
  912.   format.title "title" output.check
  913.   crossref missing$
  914.     { format.in.ed.booktitle.din "booktitle" output.check
  915.       volume empty$
  916.      'skip$
  917.      { " Bd." volume tie.or.space.connect output }
  918.       if$
  919.       address empty$
  920.     { organization new.sentence.checka
  921.       organization output
  922.       part.of.sentence
  923.       format.address.publisher.year output
  924.     }
  925.     { format.address.publisher.year "publisher" output.check }
  926.       if$
  927.     }
  928.     { format.incoll.inproc.crossref output.nonnull }
  929.   if$
  930.   note set.period.dash.check
  931.   note output 
  932.   isbn set.period.dash.check
  933.   format.isbn.issn output
  934.   part.of.sentence
  935.   format.pages output
  936.   fin.entry
  937. }
  938.  
  939. %% FUNCTION {conference} { inproceedings }
  940.  
  941. %% geaendert, 21/2/94
  942. FUNCTION {manual}
  943. { output.bibitem
  944.   author empty$
  945.     { organization empty$
  946.     'skip$
  947.     { organization output.nonnull
  948.       address output
  949.     }
  950.       if$
  951.     }
  952.     { format.authors output.nonnull }
  953.   if$
  954.   set.colon.after
  955.   format.btitle "title" output.check
  956.   format.edition output
  957.   author empty$
  958.     { organization empty$
  959.     { address output
  960.       part.of.sentence
  961.     }
  962.     'skip$
  963.       if$
  964.     }
  965.     { address ": " *  organization * output
  966.       part.of.sentence
  967.     }
  968.   if$
  969.   format.date output
  970.   pages new.sentence.checka
  971.   format.pages.book output
  972.   note set.period.dash.check
  973.   note output
  974.   fin.entry
  975. }
  976.  
  977.  
  978. %%$$$%%   geaendert KFL, 17/2/94 Standard = "Diplomarbeit", sonst TYPE="anderer Typ"
  979. FUNCTION {mastersthesis}
  980. { output.bibitem
  981.   format.authors "author" output.check
  982.   set.colon.after
  983.   format.btitle "title" output.check
  984.   address output
  985.   part.of.sentence 
  986.   school "school" output.check
  987.   part.of.sentence
  988.   "Diplomarbeit" format.thesis.type output.nonnull
  989.   part.of.sentence
  990.   format.date "year" output.check
  991.   pages new.sentence.checka
  992.   format.pages output
  993.   note set.period.dash.check
  994.   note output
  995.   fin.entry
  996. }
  997.  
  998. %% 26/2/94 hiermit werden u.a. Normen erfasst
  999. FUNCTION {misc}
  1000. { output.bibitem
  1001.   note empty$
  1002.      { title empty$ 
  1003.       { "" }
  1004.       { format.authors output
  1005.         format.title output
  1006.         howpublished output
  1007.         format.date output 
  1008.       } 
  1009.     if$
  1010.       }
  1011.       { note duplicate$ #1 #4 substring$ "Norm" =
  1012.        { output new.sentence 
  1013.          format.date output 
  1014.          format.title output
  1015.        }
  1016.        { pop$ ""
  1017.          author empty$
  1018.            { format.editors output }
  1019.            { format.authors  format.editors output.nonnull }
  1020.          if$
  1021.          set.colon.after
  1022.          format.title output
  1023.          howpublished output
  1024.          format.date output 
  1025.          note set.period.dash.check
  1026.          note output
  1027.        }
  1028.      if$
  1029.        }
  1030.    if$
  1031.   fin.entry
  1032. }
  1033.  
  1034. %% geaendert 21/2/94
  1035. FUNCTION {proceedings}
  1036. { output.bibitem
  1037.   editor empty$
  1038.     { organization empty$
  1039.      { "" } 
  1040.      { organization " (Veranst.)" * output }
  1041.       if$
  1042.     }
  1043.     { format.editors output.nonnull }
  1044.   if$
  1045.   set.colon.after
  1046.   format.btitle "title" output.check
  1047.   new.sentence
  1048.   editor empty$
  1049.     'skip$  
  1050.     {  format.proceed.organization output }
  1051.   if$
  1052.   new.sentence
  1053.   format.series.number.din emphasize output.nonnull
  1054.   volume empty$
  1055.     { "" output.nonnull } 
  1056.     { "Bd." volume tie.or.space.connect "volume" output.check }
  1057.   if$
  1058.   format.address.publisher.year "publisher" output.check
  1059.   pages  empty$
  1060.       'skip$            %%   evtl. hier new.sentence !!
  1061.       'part.of.sentence
  1062.    if$
  1063.   format.pages.book output
  1064.   note set.period.dash.check
  1065.   note output 
  1066.   isbn set.period.dash.check
  1067.   issn set.period.dash.check
  1068.   format.isbn.issn output
  1069.   fin.entry
  1070. }
  1071.  
  1072. %% geaendert 23/2/947 auch fuer Firmenschriften u."a.
  1073. FUNCTION {techreport}
  1074. { output.bibitem
  1075.   author empty$
  1076.     { format.editors "author and editor" output.check }
  1077.     { format.authors  format.editors output.nonnull }
  1078.   if$
  1079.   set.colon.after
  1080.   format.title "title" output.check
  1081.   institution new.sentence.checka
  1082.   institution empty$
  1083.      'skip$
  1084.      { " / " institution *  output.nonnull }
  1085.   if$
  1086.   format.address.publisher.year output
  1087.   number new.sentence.checka
  1088.   format.tr.number.din "number" output.check
  1089.   new.sentence
  1090.   format.pages.book output
  1091.   note "note" output.check
  1092.   isbn set.period.dash.check
  1093.   issn set.period.dash.check
  1094.   format.isbn.issn output
  1095.   fin.entry
  1096. }
  1097.  
  1098. FUNCTION {default.type} { misc }
  1099.  
  1100. MACRO {jan} {"Januar"}
  1101.  
  1102. MACRO {feb} {"Februar"}
  1103.  
  1104. MACRO {mar} {"Maerz"}
  1105.  
  1106. MACRO {apr} {"April"}
  1107.  
  1108. MACRO {mai} {"Mai"}
  1109.  
  1110. MACRO {jun} {"Juni"}
  1111.  
  1112. MACRO {jul} {"Juli"}
  1113.  
  1114. MACRO {aug} {"August"}
  1115.  
  1116. MACRO {sep} {"September"}
  1117.  
  1118. MACRO {okt} {"Oktober"}
  1119.  
  1120. MACRO {nov} {"November"}
  1121.  
  1122. MACRO {dez} {"Dezember"}
  1123.  
  1124. %%$$$  stillgelegte Beispiele fuer den Gebrauch von Kuerzeln (hier Zs-Titel).
  1125.  
  1126. %%MACRO {acmcs} {"ACM Computing Surveys"}
  1127.  
  1128. %%MACRO {acta} {"Acta Informatica"}
  1129.  
  1130. %%MACRO {cacm} {"Communications of the ACM"}
  1131.  
  1132. %%MACRO {ibmjrd} {"IBM Journal of Research and Development"}
  1133.  
  1134. %%MACRO {ibmsj} {"IBM Systems Journal"}
  1135.  
  1136. %%MACRO {ieeese} {"IEEE Transactions on Software Engineering"}
  1137.  
  1138. %%MACRO {ieeetc} {"IEEE Transactions on Computers"}
  1139.  
  1140. %%MACRO {ieeetcad}
  1141. %% {"IEEE Transactions on Computer-Aided Design of Integrated Circuits"}
  1142.  
  1143. %%MACRO {ipl} {"Information Processing Letters"}
  1144.  
  1145. %%MACRO {jacm} {"Journal of the ACM"}
  1146.  
  1147. READ
  1148.  
  1149. FUNCTION {sortify}
  1150. { purify$
  1151.   "l" change.case$
  1152. }
  1153.  
  1154. INTEGERS { len }
  1155.  
  1156. FUNCTION {chop.word}
  1157. { 's :=
  1158.   'len :=
  1159.   s #1 len substring$ =
  1160.     { s len #1 + global.max$ substring$ }
  1161.     's
  1162.   if$
  1163. }
  1164.  
  1165. %%INTEGERS { et.al.char.used }
  1166.  
  1167. %%FUNCTION {initialize.et.al.char.used}
  1168. %%{ #0 'et.al.char.used :=
  1169. %%}
  1170.  
  1171. %%EXECUTE {initialize.et.al.char.used}
  1172.  
  1173. FUNCTION {format.lab.names}
  1174. { 's :=
  1175.   s num.names$ 'numnames :=
  1176.   numnames #1 >
  1177.     { numnames #4 >
  1178.     { #3 'namesleft := }
  1179.     { numnames 'namesleft := }
  1180.       if$
  1181.       #1 'nameptr :=
  1182.       ""
  1183.     { namesleft #0 > }
  1184.     { nameptr numnames =
  1185.         { s nameptr "{ff }{vv }{ll}{ jj}" format.name$ "others" =
  1186.         { "\," *
  1187. %%              { "{\etalchar{+}}" *
  1188. %%                #1 'et.al.char.used :=
  1189.         }
  1190. %%              { s nameptr "{v{}}{l{}}" format.name$ * }
  1191.         { s nameptr "{l{}}" format.name$ * }
  1192.           if$
  1193.         }
  1194. %%          { s nameptr "{v{}}{l{}}" format.name$ * }
  1195.         { s nameptr "{l{}}" format.name$ * }
  1196.       if$
  1197.       nameptr #1 + 'nameptr :=
  1198.       namesleft #1 - 'namesleft :=
  1199.     }
  1200.       while$
  1201.       numnames #4 >
  1202.     { "\," *
  1203. %%      { "{\etalchar{+}}" *
  1204. %%        #1 'et.al.char.used :=
  1205.     }
  1206.     'skip$
  1207.       if$
  1208.     }
  1209. %%  { s #1 "{v{}}{l{}}" format.name$
  1210.     { s #1 "{l{}}" format.name$
  1211.       duplicate$ text.length$ #2 <
  1212.     { pop$ s #1 "{ll}" format.name$ #3 text.prefix$ }
  1213.     'skip$
  1214.       if$
  1215.     }
  1216.   if$
  1217. }
  1218.  
  1219. FUNCTION {author.key.label}
  1220. { author empty$
  1221.     { key empty$
  1222.     { cite$ #1 #3 substring$ }
  1223.     { key #3 text.prefix$ }
  1224.       if$
  1225.     }
  1226.     { author format.lab.names }
  1227.   if$
  1228. }
  1229.  
  1230. FUNCTION {author.editor.key.label}
  1231. { author empty$
  1232.     { editor empty$
  1233.     { key empty$
  1234.         { cite$ #1 #3 substring$ }
  1235.         { key #3 text.prefix$ }
  1236.       if$
  1237.     }
  1238.     { editor format.lab.names }
  1239.       if$
  1240.     }
  1241.     { author format.lab.names }
  1242.   if$
  1243. }
  1244.  
  1245. FUNCTION {author.key.organization.label}
  1246. { author empty$
  1247.     { key empty$
  1248.     { organization empty$
  1249.         { cite$ #1 #3 substring$ }
  1250.         { "The " #4 organization chop.word #3 text.prefix$ }
  1251.       if$
  1252.     }
  1253.     { key #3 text.prefix$ }
  1254.       if$
  1255.     }
  1256.     { author format.lab.names }
  1257.   if$
  1258. }
  1259.  
  1260. FUNCTION {editor.key.organization.label}
  1261. { editor empty$
  1262.     { key empty$
  1263.     { organization empty$
  1264.         { cite$ #1 #3 substring$ }
  1265.         { "The " #4 organization chop.word #3 text.prefix$ }
  1266.       if$
  1267.     }
  1268.     { key #3 text.prefix$ }
  1269.       if$
  1270.     }
  1271.     { editor format.lab.names }
  1272.   if$
  1273. }
  1274.  
  1275. FUNCTION {calc.label}
  1276. { type$ "book" =
  1277.   type$ "inbook" =
  1278.   or
  1279.     'author.editor.key.label
  1280.     { type$ "proceedings" =
  1281.     'editor.key.organization.label
  1282.     { type$ "manual" =
  1283.         'author.key.organization.label
  1284.         'author.key.label
  1285.       if$
  1286.     }
  1287.       if$
  1288.     }
  1289.   if$
  1290.   duplicate$
  1291.   year field.or.null purify$ #-1 #2 substring$
  1292.   *
  1293.   'label :=
  1294.   year field.or.null purify$ #-1 #4 substring$
  1295.   *
  1296.   sortify 'sort.label :=
  1297. }
  1298.  
  1299. FUNCTION {sort.format.names}
  1300. { 's :=
  1301.   #1 'nameptr :=
  1302.   ""
  1303.   s num.names$ 'numnames :=
  1304.   numnames 'namesleft :=
  1305.     { namesleft #0 > }
  1306.     { nameptr #1 >
  1307.     { "   " * }
  1308.     'skip$
  1309.       if$
  1310. %     s nameptr "{vv{ } }{ll{ }}{  ff{ }}{  jj{ }}" format.name$ 't :=
  1311. %
  1312. %     Zeile geaendert, damit die Namenszusaetze wie von, de usw nach deutscher
  1313. %     Norm richtig einsortiert werden.   27.10.94 Lueddecke
  1314. %
  1315.       s nameptr "{ll{ }}{  ff{ }}{ vv{ }}{  jj{ }}" format.name$ 't :=
  1316.       nameptr numnames = t "others" = and
  1317.     { "et al" * }
  1318.     { t sortify * }
  1319.       if$
  1320.       nameptr #1 + 'nameptr :=
  1321.       namesleft #1 - 'namesleft :=
  1322.     }
  1323.   while$
  1324. }
  1325.  
  1326. FUNCTION {sort.format.title}
  1327. { 't :=
  1328.   "A " #2
  1329.     "An " #3
  1330.       "Der " #4
  1331.     "Die " #4
  1332.       "Das " #4
  1333.         "Ein " #4
  1334.           "Eine " #5 
  1335.           "The " #4 t chop.word
  1336.            chop.word
  1337.          chop.word
  1338.        chop.word
  1339.      chop.word
  1340.        chop.word
  1341.     chop.word
  1342.   chop.word
  1343.   sortify
  1344.   #1 global.max$ substring$
  1345. }
  1346.  
  1347. FUNCTION {author.sort}
  1348. { author empty$
  1349.     { key empty$
  1350.     { "to sort, need author or key in " cite$ * warning$
  1351.       ""
  1352.     }
  1353.     { key sortify }
  1354.       if$
  1355.     }
  1356.     { author sort.format.names }
  1357.   if$
  1358. }
  1359.  
  1360. FUNCTION {author.editor.sort}
  1361. { author empty$
  1362.     { editor empty$
  1363.     { key empty$
  1364.         { "to sort, need author, editor, or key in " cite$ * warning$
  1365.           ""
  1366.         }
  1367.         { key sortify }
  1368.       if$
  1369.     }
  1370.     { editor sort.format.names }
  1371.       if$
  1372.     }
  1373.     { author sort.format.names }
  1374.   if$
  1375. }
  1376.  
  1377. FUNCTION {author.organization.sort}
  1378. { author empty$
  1379.     { organization empty$
  1380.     { key empty$
  1381.         { "to sort, need author, organization, or key in " cite$ * warning$
  1382.           ""
  1383.         }
  1384.         { key sortify }
  1385.       if$
  1386.     }
  1387.     { "The " #4 organization chop.word sortify }
  1388.       if$
  1389.     }
  1390.     { author sort.format.names }
  1391.   if$
  1392. }
  1393.  
  1394. FUNCTION {editor.organization.sort}
  1395. { editor empty$
  1396.     { organization empty$
  1397.     { key empty$
  1398.         { "to sort, need editor, organization, or key in " cite$ * warning$
  1399.           ""
  1400.         }
  1401.         { key sortify }
  1402.       if$
  1403.     }
  1404.     { "The " #4 organization chop.word sortify }
  1405.       if$
  1406.     }
  1407.     { editor sort.format.names }
  1408.   if$
  1409. }
  1410.  
  1411. FUNCTION {presort}
  1412. { calc.label
  1413.   sort.label
  1414.   "    "
  1415.   *
  1416.   type$ "book" =
  1417.   type$ "inbook" =
  1418.   or
  1419.     'author.editor.sort
  1420.     { type$ "proceedings" =
  1421.     'editor.organization.sort
  1422.     { type$ "manual" =
  1423.         'author.organization.sort
  1424.         'author.sort
  1425.       if$
  1426.     }
  1427.       if$
  1428.     }
  1429.   if$
  1430.   *
  1431.   "    "
  1432.   *
  1433.   year field.or.null sortify
  1434.   *
  1435.   "    "
  1436.   *
  1437.   title field.or.null
  1438.   sort.format.title
  1439.   *
  1440.   #1 entry.max$ substring$
  1441.   'sort.key$ :=
  1442. }
  1443.  
  1444. ITERATE {presort}
  1445.  
  1446. SORT
  1447.  
  1448. STRINGS { longest.label last.sort.label next.extra }
  1449.  
  1450. INTEGERS { longest.label.width last.extra.num }
  1451.  
  1452. FUNCTION {initialize.longest.label}
  1453. { "" 'longest.label :=
  1454.   #0 int.to.chr$ 'last.sort.label :=
  1455.   "" 'next.extra :=
  1456.   #0 'longest.label.width :=
  1457.   #0 'last.extra.num :=
  1458. }
  1459.  
  1460. FUNCTION {forward.pass}
  1461. { last.sort.label sort.label =
  1462.     { last.extra.num #1 + 'last.extra.num :=
  1463.       last.extra.num int.to.chr$ 'extra.label :=
  1464.     }
  1465.     { "a" chr.to.int$ 'last.extra.num :=
  1466.       "" 'extra.label :=
  1467.       sort.label 'last.sort.label :=
  1468.     }
  1469.   if$
  1470. }
  1471.  
  1472. FUNCTION {reverse.pass}
  1473. { next.extra "b" =
  1474.     { "a" 'extra.label := }
  1475.     'skip$
  1476.   if$
  1477.   label extra.label * 'label :=
  1478.   label width$ longest.label.width >
  1479.     { label 'longest.label :=
  1480.       label width$ 'longest.label.width :=
  1481.     }
  1482.     'skip$
  1483.   if$
  1484.   extra.label 'next.extra :=
  1485. }
  1486.  
  1487. EXECUTE {initialize.longest.label}
  1488.  
  1489. ITERATE {forward.pass}
  1490.  
  1491. REVERSE {reverse.pass}
  1492.  
  1493. FUNCTION {begin.bib}
  1494. { 
  1495. %%et.al.char.used
  1496. %%    { "\newcommand{\etalchar}[1]{$^{#1}$}" write$ newline$ }
  1497. %%    'skip$
  1498. %%  if$
  1499.   preamble$ empty$
  1500.     'skip$
  1501.     { preamble$ write$ newline$ }
  1502.   if$
  1503.   "\begin{thebibliography}{"  longest.label  * "}" * write$ newline$
  1504. }
  1505.  
  1506. EXECUTE {begin.bib}
  1507.  
  1508. EXECUTE {init.state.consts}
  1509.  
  1510. ITERATE {call.type$}
  1511.  
  1512. FUNCTION {end.bib}
  1513. { newline$
  1514.   "\end{thebibliography}" write$ newline$
  1515. }
  1516.  
  1517. EXECUTE {end.bib}
  1518.  
  1519. %% Ende von DINALPHA.BST  KFL, 28/3/94
  1520.